{
  pkgs,
  lib,
  ...
}: {
  nixpkgs.overlays = [
    (self: super: {
      nsxiv = super.nsxiv.overrideAttrs (old: {
        buildInputs = old.buildInputs ++ [pkgs.xorg.libXcursor];
        env.NIX_LDFLAGS = "-lXcursor";
        patches = [./nsxiv.diff];
      });
      maim = super.maim.overrideAttrs (old: {
        buildInputs = old.buildInputs ++ [pkgs.xorg.libXcursor];
        env.NIX_LDFLAGS = "-lXcursor";
      });
      ki = super.ki.overrideAttrs (old: {
        patches = old.patches ++ [./ki.diff];
      });
      awesome = super.awesome.overrideAttrs (old: {
        postInstall = let
          pi = lib.strings.splitString "\n" old.postInstall;
          front = lib.lists.take 5 pi;
          back = lib.lists.drop 5 pi;
          add = ''--add-flags '--search ${super.awesome.lua.pkgs.vicious}/lib/lua/${super.awesome.lua.luaversion}' \'';
        in
          lib.strings.concatLines (front ++ [add] ++ back);
      });
      cifs-utils = super.cifs-utils.overrideAttrs (old: {
        buildInputs = lib.lists.remove pkgs.libcap old.buildInputs;
      });
      wine = pkgs.symlinkJoin {
        name = "wine";
        paths = [super.wine];
        buildInputs = [pkgs.makeWrapper];
        postBuild = ''
          wrapProgram $out/bin/wine \
            --set LC_ALL "ja_JP.UTF-8"
        '';
      };
    })
  ];
}