nix-conf/overlays/default.nix

{
  lib,
  inputs,
  ...
}: {
  nixpkgs.overlays = [
    (self: super: {
      nsxiv = super.nsxiv.overrideAttrs (old: {
        buildInputs = old.buildInputs ++ [super.xorg.libXcursor];
        env.NIX_LDFLAGS = "-lXcursor";
        patches = [./nsxiv.diff];
      });
      maim = super.maim.overrideAttrs (old: {
        buildInputs = old.buildInputs ++ [super.xorg.libXcursor];
        env.NIX_LDFLAGS = "-lXcursor";
      });
      ki = super.ki.overrideAttrs (old: {
        patches = old.patches ++ [./ki.diff];
      });
      awesome = super.awesome.overrideAttrs (old: {
        postInstall = let
          pi = lib.strings.splitString "\n" old.postInstall;
          front = lib.lists.take 5 pi;
          back = lib.lists.drop 5 pi;
          add = ''--add-flags '--search ${super.awesome.lua.pkgs.vicious}/lib/lua/${super.awesome.lua.luaversion}' \'';
        in
          lib.strings.concatLines (front ++ [add] ++ back);
      });
      cifs-utils = super.cifs-utils.overrideAttrs (old: {
        buildInputs = lib.lists.remove super.libcap old.buildInputs;
      });
      wineWowPackages.stable = super.symlinkJoin {
        name = "wine";
        paths = [super.wineWowPackages.stable];
        buildInputs = [super.makeWrapper];
        postBuild = ''
          wrapProgram $out/bin/wine \
            --set LC_ALL "ja_JP.UTF-8"
        '';
      };
      pwndbg = inputs.pwndbg.packages.${super.system}.pwndbg;
      kdePackages = super.kdePackages.overrideScope (
        kself: ksuper: {
          polkit-kde-agent-1 = ksuper.polkit-kde-agent-1.overrideAttrs (old: {
            buildInputs = old.buildInputs ++ [ksuper.kirigami ksuper.sonnet];
          });
        }
      );
    })
  ];
}